函数教学-数字提取
前言
呜啦啦啦~好久不见，最近同事因为工作需要问到，怎么快速的提取一个字段中的数字，为此我总结了几种常见情况下提取文本中数字的方法供大家学习参考
一、数字与汉字之间有符号1.0
方法一：CTRL E智能填充
方法二：我们还可以使用 find 函数查找符号位置，C2 单元格输入公式如下
=LEFT(B2,FIND(“-“,B2)-1)
温馨提示：
通过 find 函数查找特殊字符所在的位置，再用 left 函数从左边开始提取数字
二、数字与汉字之间没有符号2.1
??数字在汉字左侧
同样的我们也可以用快捷键【Ctrl E】进行分列。
我们还可以借助 lenb len 函数，获取位置信息、提取数字。len 函数计算英文为1个字节，lenb函数计算汉字作为 2 个字节。因此，我们在 F2 单元格中输入以下公式：
=LEFT(E2,LEN(E2)*2-LENB(E2))
温馨提示：
本函数关键在于使用LEN(E2)*2-LENB(E2) ，就是获取左边数字的个数，配合left 函数截取左边的数字。
2.2
??数字在汉字右侧
当数字在汉字右边时，我们可以用函数 len lenb mid。
输入公式如下：
=MID(H2,LENB(H2)-LEN(H2) 1,99)
温馨提示：
LENB(H2)-LEN(H2)主要是获得左边文本的个数，加上 1 后就是首个数字出现的位数。
从首个位置开始截取到 99 位（具体提取的位数只要大于等于数字的最大位数即可）。
2.3
??数字在汉字中间
需要利用 lookup 函数配合数组公式来做。
公式如下：
=-LOOKUP(1,-MIDB(K2,SEARCHB(“?”,K2),ROW($1:$15)))
温馨提示：
这里是利用 SEARCHB 函数的通配符查找功能，查找字符串中的数字。
由于公式是一个数组公式，需要按【Ctrl＋Shift＋Enter】进行数组运算。
三、数字与字母汉字混合3
当涉及到数字、字母和汉字同时存在的情况，我们就需要使用数组公式了。数组公式需要按住Ctrl shift enter进行执行数组运算，公式的两边会出现花括号
>>>>
??数字在最右侧
=-LOOKUP(1,-RIGHT(O2,ROW($1:$15)))
>>>>
??数字在最左侧
=-LOOKUP(1,-LEFT(R2,ROW($1:$15)))
温馨提示：
首先使用 right 函数，从右到左分别截取长度为 1 到 15 的子字符串，再利用取负运算，将文本转换为错误值，将数值转换为负数；
然后利用 lookup 函数获取数组的最后一个值，最后将负数取负转为正数。
从左侧提取的数字原理，跟从右侧提取的原理相同。
>>>>
??数字在任意位置
3.1借助lookup函数
=-LOOKUP(0,-MID(K2,MIN(FIND(ROW($1:$10)-1,
K2&1/17)),ROW($1:$15)))
小解析：
1.首先利用 ROW 函数构造 0-9 的数字数组：ROW($1:$10)-1
2.「1/17」等于 0.0588235294117647，它是一个包含 0-9 所有数字的值，连接在文本的尾部是避免 FIND 函数在查找数字时，因文本缺少相应数字而返回错误值。
3.用 FIND 函数查找 10 个数字在文本中的位置，利用 MIN 函数返回文本中出现数字的最小位置，即可以得到首个数字的位置。
4.利用 MID 函数从首个数字位置开始，依次向右截取长度为 1~15 的 15 个子字符串，加上负号，将数字转化为负数，文本转化为错误值。
5.最后利用 LOOKUP 函数返回最大的数字，再使用负号将负数转化为正数。
3.2借助max函数
=MAX(IFERROR(–RIGHT(LEFT(K20,ROW($1:$13))
,COLUMN($A:$D)),0))
小解析：
1.先用 len 函数确定字符串中最长的个数。
row(1:13)——13 这个数只要大于字符串中最长的个数即可，目的是是后面一个个子字符的截取。
2. LEFT(K20,ROW($1:$13) ——从首个字符开始依次从右截取 1~13 个子字符串。
3. column(a:d)——a:d 取决于字符串中数字的最大位数。
4. RIGHT(LEFT(K20,ROW($1:$13)),COLUMN($A:$D)——从左开始向右依次截取 1~13 个子字符，再从此数组的基础上从右开始依次向左截取 1~4 个子字符，此时是一个 13*4 的数组。
5. 公式前加–，是为了将文本转为错误值。
6. 将错误值转换为 0，从数组选出最大值，即可获得最大数字。
本期内容干货满满，觉得对你有所帮助的同学可以自己动手尝试做几次加强熟练度，关于提取单元格数字的方法还有很多种，在熟练掌握各种公式后可以有更好的组合方式，也可以留言告诉我哦，今天是三八妇女节，也祝所有的女生节日快乐~
END
